#REM    Li-Ion Battery Management System Slave Module by Peter Perkins.
       Picaxe 08M - PIC12F683 - 280708 - www.150mpg.co.uk - V0.63 Beta.
**************************** General Information ******************************

The BMS modules carry no warranty or guarantee, and are used at the owners own
risk. No liability will be entertained in any shape or form whatsoever.
The modules and software have been produced for the benefit of the EV and
electronic community. The software, hardware and source files, inc pcb layouts
are made available free via the internet. Users may modify or adapt the system
as they see fit. If you are not fully competent to work on potentially lethal
battery systems and voltages, then do not experiment with/use this system.   

************************* Slave Picaxe 08M Pinouts ****************************

                                    Top					
                                   _____
(+ Cell Supply)             +Ve -1|  ^  |8- -Ve               (- Cell Supply)
(Program In)                Rxd -2|  0  |7- Output 0           (Data Bus Out)
(Interrupt Out)        Output 4 -3|  8  |6- Output 1        (Bypass Load Out)
(Interrupt in)          Input 3 -4|  M  |5- Input 2        (RefAdc In 1.235V) 
                                   ----- 

************************ Slave Module Specification ***************************

Supply/Cell Voltage 1.75 - 5.00V DC (Pic limits)
Average Supply Current at 4.00v <100ua
Voltage Ref LM 385 1.235V accuracy 1%
Supply/Cell Voltage sensing accuracy +/- 30mv
Maximum balancing/bypass current 333ma at 5.00V
Serial Bus data rate 4800 baud (Picaxe 08M limit at 8mhz)
Maximum Cell Capacity 65ah (65,000) (Limit of 16bit Word Variable)
Maximum 128 Slave Modules per Master Module (Pic Scratchpad Ram limit)
CPU Speed 8mhz with internal resonator 
Permitted Working Cell Voltage Range 1.75 - 4.30V
RefVADC should be 1263 but can be adjusted to compensate for variations. 

*******************************************************************************
#ENDREM

`Variables Constants and I/O definitions

`Variables 16bit

symbol CellV	   = w0		;w0 = Corrected Cell voltage (16bit value)
symbol RefADC      = w1		;w1 = Raw Adc input data variable range 0-1024 10bit
symbol CellA       = w2		;w2 = Cell average voltage last 10 measurements

`Variables 8bit

symbol VData       = b0		;b0 = Voltage data byte  (8bit value) (Sent to Master via link)
symbol Counter     = b13	;b13 = General 0-255 byte ADC loop counter variable

`Constants

symbol RefVADC        = 1270 	;RefVADC = Fixed Ref Voltage LM385 1.235v * 1023 = 1270 (1250-1280)
symbol MaxCellV       = 370	;Maximum Cell Voltage 3.70v (Balancing load/bypass cut in point) 
symbol Delay          = 10	;Interrupt and data delay time in milliseconds (10ms)
symbol DLow           = 175	;Cell correction value 175 or 1.75V subtracted from CellVoltage 
symbol DHigh          = 430	;Cell correction value 430 or 4.30V (If Cell V>430 or <175 then error)

`Pins used for I/O and designations

`*** Digital high/low Outputs ***

symbol SlaveData     = 0    	;Slave Data Bus 4800baud on Output 0
symbol Load          = 1	;2W 15R Transistor driven load/bypass resistor on Output 1
symbol Led           = 4	;Red Interrupt Indicator Led on Output 4

`*** Analogue ADC Inputs ***

symbol RefInput      = 2	;LM385 1.235V RefAdc on Input 2

`*******************************************************************************
`*******************************************************************************

Start:				;Main program start

	setfreq m8		;Setfreq CPU Freq to 8mhz
	disablebod		;Disable Pic Chip Brown Out Detection to function at lower supply V

`*******************************************************************************
`*******************************************************************************

Main:						;Main program loop label

	CellA = 0 				;Set Cell Average word variable to 0 (Zero)
	
	for Counter = 1 to 10			;10x ADC Oversampling loop counter
	readadc10 RefInput, RefADC		;Measure ADC voltage reference
	CellA = CellA + RefADC			;Add latest ADC reading to running total
	next Counter				;Repeat loop until 10 ADC readings obtained
	
	CellA = CellA / 10			;Calculate average ADC reading for last 10 readings
	CellV = RefVADC *25 / CellA * 100 / 25 	;Calculate Cell Voltage from the average ADC reading

	if CellV > MaxCellV then		;If Cell V > MaxCellVoltage (3.75v) then
	high Load				;Turn on load (and load indicator led If fitted)
	else
	low Load				;Turn off load (and load indicator led if fitted)
	endif

	if pin3 = 1 then gosub Interrupt	;If pin 3 is high then there is an active data request
		
	goto main				;Goto main loop

`********************************************************************************

Interrupt:					;Interrupt data transmission routine

	pause Delay				;Pause 0.01 of a second
	
	if CellV >DHigh or CellV <DLow then	;If V >4.30V or V <1.75V set out of range (b0=0)	
	b0 = 0					;Set b0=0 Cell error out of Voltage range condition
	else
	CellV = CellV - DLow		 	;Convert Word (CellV) data into Byte (VData) for output
	endif

	serout SlaveData,N2400,(VData)		;Send VData (b0) to Master at 2400bps x2 (4800bps at 8mhz)

	high Led				;Turn on Next Cell Interrupt trigger/indicator
	pause Delay				;Pause 0.01 of a second
	low Led					;Turn off Interrupt trigger/indicator led

	return					;Return from interrupt to main program