#REM   Li-Ion Battery Management System Slave (Analogue On/Off Charger Control) 
By Peter Perkins. Picaxe 08M - PIC12F683 - 120908 - www.150mpg.co.uk - V1.07 Beta.
**************************** General Information *********************************

The BMS modules carry no warranty or guarantee of any kind! They are used at
your own risk, and I make no claims as to their suitability for a particular
function. Prospective users must evaluate the system before using it, and no
liability will be entertained by myself in any shape or form whatsoever.
The modules and software have been produced at low cost for the benefit of
the EV & electronic community. The software is available free via the internet.
Users may modify or adapt the system as they see fit. If you are not fully
competent to work on potentially lethal battery systems and high voltages,
then do not experiment with or use this system. Be aware that vehicle
modifications can lead to invalidated insurance and warranty issues. You the
end user remain fully liable for any modifications made to your vehicle.   

************************* Slave Picaxe 08M Pinouts *******************************
                                    				
                                    Top					
                                   _____
(+ Cell Supply)             +Ve -1|  ^  |8- -Ve                    (- Cell Supply)
(Program In)                Rxd -2|  0  |7- Output 0             (Bypass Load Out)
(Slave Bus Out/Low V   Output 4 -3|  8  |6- Input 1             (RefAdc In 1.235V) 
(Slave Data Bus In)     Input 3 -4|  M  |5- Output 2       (Master Bus Out/High V)
                                   ----- 

************************ Slave Module Specification ******************************

Supply/Cell Voltage 1.75 - 5.00V DC (Pic limits)
Average Supply Current at 4.00v <100ua
Voltage Ref LM 385 1.235V accuracy 1%
Supply/Cell Voltage sensing accuracy +/- 30mv
Maximum balancing/bypass current with 15R resistor 333ma at 5.00V
Maximum serial Bus data rate 4800 baud (Picaxe 08M limit at 8mhz)
Maximum cell Capacity 65ah (65,000) (Limit of 16bit Word Master Variable)
Maximum 128 Slave Modules per Master Module (Master Pic Scratchpad Ram limit)
CPU Speed 31khz - 8mhz with internal resonator (Lower speed used for power saving) 
Permitted Working Cell Voltage Range 1.75 - 4.30V
RefVADC should be 1263 but can be adjusted to compensate for variations. 
Note Slave Opto's are Sink driven therefore (Pic Output Low = Opto On, High = Opto Off)

***************************** Slave Clock Speeds *********************************
*********************** Reducing CPU Speed Saves Power ***************************
******** Use the slowest speed setting that gives acceptable performance *********

%00000000 = 31 kHz 19bps
%00010000 = 125 kHz 75bps
%00100000 = 250 kHz 150bps
%00110000 = 500 kHz 300bps
%01000000 = 1 MHz 600bps
%01010000 = 2 MHz 1200bps
%01100000 = 4 MHz 2400bps
%01110000 = 8 MHz 4800bps

Example = poke $8F,%01100000 'Set clock to 4 MHz

**********************************************************************************
********************** Program Size 70 out of 256 Bytes **************************
**********************************************************************************

***************************** Simulation Notes ********************************

Use a generic adc input of 650 to simulate a cell voltage of 1.92V
Use a generic adc input of 400 to simulate a cell voltage of 3.16V 
Use a generic adc input of 300 to simulate a cell voltage of 4.20V 

#ENDREM

`Variables Constants and I/O definitions

`Variables 16bit

symbol CellV	   = w0		;w0 (b0,b1) = Cell voltage (16bit value)
symbol RefADC      = w1		;w1 (b2,b3) = Raw Adc input data variable range 0-1023 10bit

`Constants

symbol RefVADC     = 1270       ;Fixed Ref Voltage Calibration LM385 1.235v * 1023 = 1270 (1250-1280)

symbol ChargerCutOutV = 380	;Charger cut off Voltage 
symbol ChargerCutInV  = 360	;Charger start up Voltage 

symbol LoadCutInV  = 360	;Balancing load/bypass cut in Voltage 
symbol LoadCutOutV = 350	;Balancing load/bypass cut out Voltage 

symbol MinCellV    = 250        ;Minimum Cell Voltage 2.50v (Assist/Controller cutback point) 

`Pins used for I/O and designations

`*** Digital high/low Outputs ***

symbol Load          = 0	;2W 15R Transistor driven load/bypass resistor on Output 0
symbol HighOpto      = 2    	;HighOpto on Output 2
symbol LowOpto       = 4	;LowOpto on Output 4

`*** Analogue ADC Inputs ***

symbol RefInput      = 1	;LM385 1.235V RefAdc on Input 1

`**********************************************************************************
`**********************************************************************************

Start:				;Main program start

	disablebod		;Disable Pic Chip Brown Out Detection to function at lower supply V
	poke $8F,%00010000	;Set CPU to 125khz for minimal power consumption

`**********************************************************************************

Main:						;Main program loop label
	
	readadc10 RefInput, RefADC		;Measure ADC voltage reference
	
	CellV = RefVADC *25 / RefADC * 100 / 25 ;Calculate Cell Voltage from the ADC LM385 VRef 1.235v reading
	
	if CellV > ChargerCutOutV then		;If Cell V > ChargerCutOutV (3.80v initial Value) then
	low HighOpto				;Turn on HighOpto (Warning/Charger/Controller/Regen Cutback) {Stop Charger}
	endif	

	if CellV < ChargerCutInV then		;If Cell V < ChargerCutInV (3.60v initial Value) then
	high HighOpto				;Turn off HighOpto (Warning/Charger/Controller/Regen Cutback) {Start Charger}
	endif	
	
	if CellV > LoadCutInV then		;If Cell V > LoadCutInV then
	high Load				;Turn on load (and load indicator led If fitted)
	endif
	
	if CellV < LoadCutOutV then		;If Cell V < LoadCutOutV then
	low Load				;Turn off load (and load indicator led if fitted)
	endif
	
	if CellV < MinCellV then		;If Cell V < MinCellV (2.50 initial Value) then
	low LowOpto				;Turn on LowOpto (Warning/Assist/Controller Cutback) & led if fitted
	else
	high LowOpto				;Turn off LowOpto (Warning/Assist/Controller Cutback) & led if fitted
	endif

	goto Main				;Goto program main loop